新企画　コメント参加型、逐次改良ミニゲームをホームページで公開してみる

　だから報告する事が無いんだけど、折角のゴールデンウィークだし、じゃあ別の企画をと思ってコメント参加型の簡単ブラウザゲームを作っていってみる事にした。

　1マップ防衛シューティングをコメントを参考にしながら作っていく

　
　
　ほんとは作りたいゲームアイデアだけは沢山あるんだけど形にするのが大変で、今回ももう 1年も使ってるし、だからメインの時間じゃ無くて夕食後の空いた時間とかに簡単なミニゲームを改良しながら公開する方式で、ちまちまと作る事にしてみる。

　改良とか実装にはみなさんのコメントの書き込みを参考にして逐次改良していく方式の予定で、コメント無ければ自分で適当にいじっていきます。

　こういう要素を実装してみてとか、グラとか音とかの要望とか、ゲームの方向性とか設定とか、なんでもかまいませんので書いてみてください。

　ここにでは無くてホームページのゲーム記事のコメント欄にお願いします。

　なお、ヒマな時間余裕のある時間に気が向いたらいじる予定なので、実装に時間がかかったり、きびしくなったら突然消えて失踪もありえると思うので、あらかじめご了承下さい。

　合わせて多少プログラム講座っぽくしてみる予定だけど、まあ HSPだし自分には教えるほどの技術がある訳じゃ全く無いので参考程度の内容になるでしょう。

　ああ、それと費用対効果はアフィリエイト、つまり広告バナーを予定してます。
　
　
　企画第一弾のゲームはコチラ

　と言う事で「1マップ防衛シューティング」という極めて初歩的で作るのが簡単なゲームです。
　
　
ver.0.001のソースはコレ

; 企画第一弾 : 1画面防衛シューティングを作ろう
; var.0.001

#include "hsp3dish.as" ; HSPdishの宣言


	randomize	; 乱数の初期化

	wx=640	; 画面の大きさx
	wy=360	; 画面の大きさy

	ox=20	; キャラ大きさx
	oy=20	; キャラ大きさy

	font "",ox	; キャラの大きさ設定

	px=wx/2-ox/2	; プレイヤーの座標x
	py=wy/2-oy/2	; プレイヤーの座標y

	sf=0		; ショット発射フラグ
	sx=0.0		; ショット座標x
	sy=0.0		; ショット座標y
	ssp=7.0		; スピード

	eb=20		; 敵最大数
	 dim ef,eb	; 出現フラグ
	 ddim ex,eb	; 敵座標x
	 ddim ey,eb	; 敵座標y
	 ddim edx,eb; 敵移動量x
	 ddim edy,eb; 敵移動量y

	esp=1.0		; 敵スピード

	ec=0		; 出現カウント
	ecb=10		; 出現間隔(フレーム)

	scr=0		; スコア
	hiscr=0		; ハイスコア


*main

	mainf=0 ; ゲームフラグ

	repeat ; メインループ ----------------------------------

	 x=mousex : y=mousey	; マウスの座標


; SHOT ----------

	 if sf=0 { ; 弾が発射されて無い
		sx=double(px) : sy=double(py)	; 初期座標

		xn=double(x-px)	; 自機とマウスの距離x
		yn=double(y-py)	; 自機とマウスの距離y

		rad=atan(xn,yn) ; 距離xyから角度を求める

	 	sdx=sin(rad)*ssp	; 角度とスピードから移動量xを求める
	 	sdy=cos(rad)*ssp	; 角度とスピードから移動量yを求める

		sf=1	; 発射フラグ on
	 }

	 if sf=1 { ; 弾が発射されている

		sx+=sdx ; xの移動
		sy+=sdy	; yの移動

		repeat eb ; 敵との当たり判定
		 if ef(cnt)=0 : continue

		 if sx<ex(cnt)+ox and ex(cnt)<sx+ox and sy<ey(cnt)+oy and ey(cnt)<sy+oy {
			ef(cnt)=0 : sf=0 ; 当たった敵とショットを消す
			scr+ ; スコア
			if hiscr<scr : hiscr=scr ; ハイスコアの更新
			break
		 }
		loop

		if sf=1 : if sx<0-ox or wx<sx or sy<0-oy or wy<sy : sf=0 ; 枠外でフラグ off
	 }


; ENEMY ----------

	 repeat 1 ; 敵出現
	  if ec>0 : ec- : break ; ウエイト中

	  repeat eb ; フラグ確認
	   if ef(cnt)>0 : continue ; 使用中
	   ef(cnt)=1 ; 使用フラグon

	   r=rnd(4) ; 出現方向
	    if r=0 : exs=rnd(wx) : eys=-oy	; 上
	    if r=1 : exs=rnd(wx) : eys=wy	; 下
	    if r=2 : exs=-ox : eys=rnd(wy)	; 左
	    if r=3 : exs=wx  : eys=rnd(wy)	; 右

		ex(cnt)=double(exs)	; 初期位置x
		ey(cnt)=double(eys)	; 初期位置y

		xn=double(px-exs)	; 敵と自機の距離x
		yn=double(py-eys)	; 敵と自機の距離y

		rad=atan(xn,yn) 	; 距離xyから角度を求める

	 	edx(cnt)=sin(rad)*esp	; 角度とスピードから移動量xを求める
	 	edy(cnt)=cos(rad)*esp	; 角度とスピードから移動量yを求める

		ec=ecb ; 出現ウエイト

	   break ; 登録終わり
	  loop
	 loop

	 repeat eb
	  if ef(cnt)=0 : continue ; 無し

	  ex(cnt)+=edx(cnt) : ey(cnt)+=edy(cnt) ; 移動

	  if px<ex(cnt)+ox and ex(cnt)<px+ox and py<ey(cnt)+oy and ey(cnt)<py+oy {
		mainf=1 : break ; 自機と当たりで GAME OVER
	  }

	  if ex(cnt)<0-ox or wx<ex(cnt) or ey(cnt)<0-oy or wy<ey(cnt) : ef(cnt)=0 ; 枠外でフラグ off
	 loop

	 redraw 0 ; 表示
	  color 1,1,1 : boxf	; 黒塗り
	  color 255,255,255
	   pos px,py : mes "●" ; 自機
	   pos sx,sy : mes "・" ; ショット

	   repeat eb
	    if ef(cnt)=0 : continue ; 無い
	    pos ex(cnt),ey(cnt) : mes "敵" ; 敵
	   loop

	   pos wx-300,5 : mes "SCORE "+scr
	   pos wx-150,5 : mes "HI SCORE "+hiscr

	   if mainf=1 : pos wx/2-43,wy/2+50 : mes "GAME OVER"
	 redraw 1

	 await 1000/15	; ウエイト、FPS 15


	 repeat ; GAME OVER 表示待機 -----------
	  if mainf=0 : break

	  await 1000/15
	  stick k : if k=0 : continue ; ボタンでゲーム再開

	　repeat eb
	   ef(cnt)=0 ; 敵リセット
	  loop

	  sf=0 ; ショットリセット

	  scr=0 ; スコアリセット

	  mainf=0 ; ゲーム再開

	  break
	 loop ; ----------

	loop ; --------------------------------------------------

end ; 終わり

　とりあえずプロトタイプ 1号はこれだけで動きます。
　
　

プログラム講座というか説明